package {
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.geom.Point;
 
	public class MouseAvoider extends Sprite {
 
		private const DISTANCE_DIVISOR:uint = 10; //see moveToDestination()
		private const FRICTION:Number= .9;
		private const FEAR_DISTANCE:Number= 150; //if mouse gets closer than this value  sprite moves away
		private const MAX_AVOID_FORCE:uint = 10; //maximum length of avoid vector
 
		private var _destinationPoint:Point; //destination point
		private var _speed:Point = new Point(0, 0); //speed vector
 
		public function MouseAvoider():void {
 
			drawStuff();
		}
 
		private function drawStuff():void {
 
			graphics.beginFill(Math.random() * 0xFFFFFF)
			graphics.drawCircle(0, 0, 10);
			graphics.endFill();
		}
 
		public function set destinationPoint(value:Point):void {
 
			_destinationPoint = value;
 
			addEventListener(Event.ENTER_FRAME, move);
		}
		protected function move(e:Event):void {
 
			moveToDestination();
			avoidMouse();
			applyFriction();
			updatePosition();
		}
 
		private function moveToDestination():void {
 
			_speed.x += (_destinationPoint.x - x) / DISTANCE_DIVISOR;
			_speed.y += (_destinationPoint.y - y) / DISTANCE_DIVISOR;
		}
 
		private function avoidMouse():void{
 
			var currentPosition:Point = new Point(x, y);
			var mousePosition:Point = new Point(stage.mouseX, stage.mouseY);
			var distance:uint = Point.distance(currentPosition, mousePosition);
 
			if (distance < FEAR_DISTANCE) {
 
				var force:Number = (1 - distance / FEAR_DISTANCE) * MAX_AVOID_FORCE;
				var gamma:Number = Math.atan2(-mousePosition.y + currentPosition.y, -mousePosition.x + currentPosition.x);
				var avoidVector:Point = Point.polar(force, gamma);
 
				_speed.x += avoidVector.x;
				_speed.y += avoidVector.y;
			}
		}
		private function applyFriction():void {
 
			_speed.x *= FRICTION;
			_speed.y *= FRICTION;
		}
		private function updatePosition():void{
 
			x += _speed.x;
			y += _speed.y;
		}
 
	}
}